Données d’exportation de Quartus® II Tcl dans le fichier CSV

De nombreux concepteurs utilisent Excel à un stade quelconque d’une conception FPGA. Il est facile d’exporter les données d’un panneau de rapport Quartus II vers un fichier CSV que vous pouvez ouvrir dans Excel.

Cette procédure simple exporte les données d’un panneau de rapport spécifié et les écrit dans un fichier. Un projet doit être ouvert lorsque vous appelez cette procédure. Un exemple d’utilisation dans un script suit.

proc panel_to_csv { panel_name csv_file } {

    set fh [open $csv_file w]
    load_report
    set num_rows [get_number_of_rows -name $panel_name]

    # Go through all the rows in the report file, including the
    # row with headings, and write out the comma-separated data
    for { set i 0 } { $i < $num_rows } { incr i } {
        set row_data [get_report_panel_row -name $panel_name -row $i]
        puts $fh [join $row_data ","]
    }

    unload_report
    close $fh
}

Voici un script qui utilise la procédure. Exécutez cette fonctionnalité dans une invite de commande système possédant la commande ci-dessous.

load_package report
package require cmdline

proc panel_to_csv { panel_name csv_file } {

    set fh [open $csv_file w]
    load_report
    set num_rows [get_number_of_rows -name $panel_name]

    # Go through all the rows in the report file, including the
    # row with headings, and write out the comma-separated data
    for { set i 0 } { $i < $num_rows } { incr i } {
        set row_data [get_report_panel_row -name $panel_name -row $i]
        puts $fh [join $row_data ","]
    }

    unload_report
    close $fh
}

set options {\
    { "project.arg" "" "Project name" } \
    { "revision.arg" "" "Revision name" } \
    { "panel.arg" "" "Panel name" } \
    { "file.arg" "" "Output file name"} \
}
array set opts [::cmdline::getoptions quartus(args) $options]

project_open $opts(project) -revision $opts(revision)

panel_to_csv $opts(panel) $opts(file)

unload_report

Vous pouvez exécuter ce script à l’invite de commandes avec la commande suivante.

quartus_sh -t script.tcl -project <project name> -revision <revision name> -panel <panel name> -file <file name>

Assurez-vous de deviser l’argument de nom du panneau correctement si vous y entrez à l’invite de commande du système. Certains caractères, tels que la barre verticale (|) ont une signification spéciale à un shell de commande.